1// One explicit time step (symplectic Euler) of the von Karman plate.
2//
3// State layout (structure of arrays, n = nx * ny nodes):
4// pos: [u | v | w | wLo] wLo carries the rounding error of the w update
5// vel: [du | dv | dw]
6// Each 16x16 workgroup loads its tile plus a 2-node halo of w and of the node
7// weights into shared memory once, so the stencils below never touch global
8// memory. Nodes outside the sheet (weight 0) are skipped: a second difference
9// exists only where the node and both neighbours belong to the sheet, and a
10// cell contributes only when its four corners do. That reproduces the free
11// edge of the rectangle and gives a staircase free edge for an ellipse.
13@group(0) @binding(0) var<uniform> P: Params;
14@group(0) @binding(1) var<uniform> SP: StepParams;
15@group(0) @binding(2) var<storage, read> posIn: array<f32>;
16@group(0) @binding(3) var<storage, read> velIn: array<f32>;
17@group(0) @binding(4) var<storage, read_write> posOut: array<f32>;
18@group(0) @binding(5) var<storage, read_write> velOut: array<f32>;
19@group(0) @binding(6) var<storage, read_write> hist: array<f32>; // [slot * n + node] velocity of w at the audio sample instants
20// Constraint reaction (acceleration of w) per node, followed by two 4-float
21// slots of drumstick state (position, velocity, force, max force).
22@group(0) @binding(7) var<storage, read_write> react: array<f32>;
23@group(0) @binding(8) var<storage, read> w0: array<f32>; // stress-free initial shape
25const TILE = 16;
26const HALO = 2;
27const TW = 20; // TILE + 2 * HALO
28var<workgroup> tw: array<f32, 400>;
29// Node weights of the same tile in quarters (0..4), packed four to a word to stay
30// within the default 16 KB of workgroup storage.
31var<workgroup> tn: array<u32, 100>;
32// Membrane force contributions of the 17x17 cells around the tile, 4 nodes x 3 components each.
33const CT = 17;
34var<workgroup> cellF: array<f32, 3468>;
36// Tile origin in global node coordinates (set once per invocation).
37var<private> ox: i32;
38var<private> oy: i32;
39var<private> ihx2: f32;
40var<private> ihy2: f32;
41var<private> ihxy: f32;
43fn id(i: i32, j: i32) -> u32 { return u32(j) * P.nx + u32(i); }
44fn lidx(i: i32, j: i32) -> u32 { return u32(j - oy) * u32(TW) + u32(i - ox); }
45// Global indices; the tile covers [ox, ox + TW) x [oy, oy + TW).
46fn W(i: i32, j: i32) -> f32 { return tw[lidx(i, j)]; }
47fn NWq(i: i32, j: i32) -> u32 { let l = lidx(i, j); return (tn[l >> 2u] >> ((l & 3u) * 8u)) & 0xFFu; }
48fn NW(i: i32, j: i32) -> f32 { return 0.25 * f32(NWq(i, j)); }
49fn INS(i: i32, j: i32) -> bool { return NWq(i, j) != 0u; }
50fn insCell(ci: i32, cj: i32) -> bool { return INS(ci, cj) && INS(ci + 1, cj) && INS(ci + 1, cj + 1) && INS(ci, cj + 1); }
51fn U(i: i32, j: i32) -> f32 { return posIn[id(i, j)]; }
52fn V(i: i32, j: i32) -> f32 { return posIn[P.n + id(i, j)]; }
53fn DW(i: i32, j: i32) -> f32 { return velIn[2u * P.n + id(i, j)]; }
54fn W0(i: i32, j: i32) -> f32 { return w0[id(i, j)]; }
56// Weighted bending "moments" at nodes; zero where the second difference is undefined.
57fn Ma(i: i32, j: i32) -> f32 {
58 if (!(INS(i - 1, j) && INS(i, j) && INS(i + 1, j))) { return 0.0; }
59 let a = (W(i + 1, j) - 2.0 * W(i, j) + W(i - 1, j)) * ihx2;
60 var b = 0.0;
61 if (INS(i, j - 1) && INS(i, j + 1)) { b = (W(i, j + 1) - 2.0 * W(i, j) + W(i, j - 1)) * ihy2; }
62 return NW(i, j) * (a + P.nu * b);
63}
64fn Mb(i: i32, j: i32) -> f32 {
65 if (!(INS(i, j - 1) && INS(i, j) && INS(i, j + 1))) { return 0.0; }
66 let b = (W(i, j + 1) - 2.0 * W(i, j) + W(i, j - 1)) * ihy2;
67 var a = 0.0;
68 if (INS(i - 1, j) && INS(i + 1, j)) { a = (W(i + 1, j) - 2.0 * W(i, j) + W(i - 1, j)) * ihx2; }
69 return NW(i, j) * (b + P.nu * a);
70}
71// Mixed second difference at a cell center; zero outside the sheet.
72fn Cc(ci: i32, cj: i32) -> f32 {
73 if (!insCell(ci, cj)) { return 0.0; }
74 return (W(ci + 1, cj + 1) - W(ci + 1, cj) - W(ci, cj + 1) + W(ci, cj)) * ihxy;
75}
77// Membrane forces of the bilinear cell (ci, cj) on its four nodes (2x2 Gauss),
78// written to cellF at local cell index lc.
79fn cellForces(ci: i32, cj: i32, lc: u32) {
80 let base = lc * 12u;
81 if (!insCell(ci, cj)) {
82 for (var q = 0u; q < 12u; q++) { cellF[base + q] = 0.0; }
83 return;
84 }
85 let Un = vec4f(U(ci, cj), U(ci + 1, cj), U(ci + 1, cj + 1), U(ci, cj + 1));
86 let Vn = vec4f(V(ci, cj), V(ci + 1, cj), V(ci + 1, cj + 1), V(ci, cj + 1));
87 let W0n = vec4f(W0(ci, cj), W0(ci + 1, cj), W0(ci + 1, cj + 1), W0(ci, cj + 1));
88 let Wn = vec4f(W(ci, cj), W(ci + 1, cj), W(ci + 1, cj + 1), W(ci, cj + 1)) + W0n; // total shape
89 let q = 0.25 * P.hx * P.hy;
90 let ihx = 1.0 / P.hx; let ihy = 1.0 / P.hy;
91 let g3 = 0.57735026918962576;
92 var Fu = vec4f(0.0); var Fv = vec4f(0.0); var Fw = vec4f(0.0);
93 for (var gp = 0; gp < 4; gp++) {
94 var xi = -g3; if ((gp & 1) != 0) { xi = g3; }
95 var eta = -g3; if ((gp & 2) != 0) { eta = g3; }
96 let dNdx = vec4f(-(1.0 - eta), 1.0 - eta, 1.0 + eta, -(1.0 + eta)) * (0.5 * ihx);
97 let dNdy = vec4f(-(1.0 - xi), -(1.0 + xi), 1.0 + xi, 1.0 - xi) * (0.5 * ihy);
98 let ux = dot(dNdx, Un); let uy = dot(dNdy, Un);
99 let vx = dot(dNdx, Vn); let vy = dot(dNdy, Vn);
100 let wx = dot(dNdx, Wn); let wy = dot(dNdy, Wn);
101 let w0x = dot(dNdx, W0n); let w0y = dot(dNdy, W0n);
102 // Marguerre strains: total slope minus the stress-free slope.
103 let exx = ux + 0.5 * (wx * wx - w0x * w0x);
104 let eyy = vy + 0.5 * (wy * wy - w0y * w0y);
105 let gxy = uy + vx + wx * wy - w0x * w0y;
106 let Nxx = P.C * (exx + P.nu * eyy);
107 let Nyy = P.C * (eyy + P.nu * exx);
108 let Nxy = P.G * gxy;
109 Fu -= q * (Nxx * dNdx + Nxy * dNdy);
110 Fv -= q * (Nyy * dNdy + Nxy * dNdx);
111 Fw -= q * ((Nxx * wx + Nxy * wy) * dNdx + (Nxy * wx + Nyy * wy) * dNdy);
112 }
113 for (var a = 0u; a < 4u; a++) {
114 cellF[base + a * 3u] = Fu[a];
115 cellF[base + a * 3u + 1u] = Fv[a];
116 cellF[base + a * 3u + 2u] = Fw[a];
117 }
118}
120// Stored membrane force on local node `a` of cell (ci, cj).
121fn cellForce(ci: i32, cj: i32, a: u32) -> vec3f {
122 let lc = u32(cj - oy - 1) * u32(CT) + u32(ci - ox - 1);
123 let base = lc * 12u + a * 3u;
124 return vec3f(cellF[base], cellF[base + 1u], cellF[base + 2u]);
125}
127@compute @workgroup_size(16, 16)
128fn main(@builtin(global_invocation_id) gid: vec3u, @builtin(local_invocation_id) lid: vec3u, @builtin(workgroup_id) wid: vec3u) {
129 let n = P.n;
130 ox = i32(wid.x) * TILE - HALO;
131 oy = i32(wid.y) * TILE - HALO;
132 ihx2 = 1.0 / (P.hx * P.hx); ihy2 = 1.0 / (P.hy * P.hy); ihxy = 1.0 / (P.hx * P.hy);
133 // Cooperative load of the w and weight tiles (400 entries each, 256 threads).
134 let lt = lid.y * 16u + lid.x;
135 for (var e = lt; e < 400u; e += 256u) {
136 let gi = ox + i32(e % u32(TW)); let gj = oy + i32(e / u32(TW));
137 var ww = 0.0;
138 if (gi >= 0 && gi < i32(P.nx) && gj >= 0 && gj < i32(P.ny)) { ww = posIn[2u * n + id(gi, gj)]; }
139 tw[e] = ww;
140 }
141 if (lt < 100u) {
142 var word = 0u;
143 for (var q = 0u; q < 4u; q++) {
144 let e = lt * 4u + q;
145 let gi = ox + i32(e % u32(TW)); let gj = oy + i32(e / u32(TW));
146 var wq = 0u;
147 if (gi >= 0 && gi < i32(P.nx) && gj >= 0 && gj < i32(P.ny)) { wq = u32(round(4.0 * nw[id(gi, gj)])); }
148 word |= wq << (q * 8u);
149 }
150 tn[lt] = word;
151 }
152 workgroupBarrier();
153 // Membrane forces of the 17x17 cells adjacent to the tile's nodes.
154 for (var e = lt; e < 289u; e += 256u) {
155 let lci = i32(e % u32(CT)); let lcj = i32(e / u32(CT));
156 cellForces(ox + 1 + lci, oy + 1 + lcj, e);
157 }
158 workgroupBarrier();
160 let i = i32(gid.x); let j = i32(gid.y);
161 if (i >= i32(P.nx) || j >= i32(P.ny)) { return; }
162 let k = id(i, j);
163 let weight = NW(i, j);
164 if (weight == 0.0) {
165 // Outside the sheet: the node stays at rest.
166 posOut[k] = 0.0; posOut[n + k] = 0.0; posOut[2u * n + k] = 0.0; posOut[3u * n + k] = 0.0;
167 velOut[k] = 0.0; velOut[n + k] = 0.0; velOut[2u * n + k] = 0.0;
168 if ((SP.flags & 2u) != 0u) { react[k] = 0.0; }
169 return;
170 }
172 let bend = (Ma(i - 1, j) - 2.0 * Ma(i, j) + Ma(i + 1, j)) * ihx2
173 + (Mb(i, j - 1) - 2.0 * Mb(i, j) + Mb(i, j + 1)) * ihy2
174 + 2.0 * (1.0 - P.nu) * (Cc(i, j) - Cc(i - 1, j) - Cc(i, j - 1) + Cc(i - 1, j - 1)) * ihxy;
175 var F = vec3f(0.0, 0.0, -P.D * P.hx * P.hy * bend);
176 F += cellForce(i, j, 0u);
177 F += cellForce(i - 1, j, 1u);
178 F += cellForce(i - 1, j - 1, 2u);
179 F += cellForce(i, j - 1, 3u);
180 let mass = P.rhoh * P.hx * P.hy * weight;
181 var acc = F * (1.0 / mass);
183 // Loss: frequency-independent on all components, frequency-dependent (graph Laplacian) on w.
184 let vel = vec3f(velIn[k], velIn[n + k], velIn[2u * n + k]);
185 var lap = 0.0;
186 if (INS(i - 1, j)) { lap += (DW(i - 1, j) - vel.z) * ihx2; }
187 if (INS(i + 1, j)) { lap += (DW(i + 1, j) - vel.z) * ihx2; }
188 if (INS(i, j - 1)) { lap += (DW(i, j - 1) - vel.z) * ihy2; }
189 if (INS(i, j + 1)) { lap += (DW(i, j + 1) - vel.z) * ihy2; }
190 acc -= 2.0 * SP.sigma0 * vel;
191 acc.z += 2.0 * SP.sigma1 * lap;
192 // In-plane (stretching) waves lie at several kHz; they get their own loss.
193 acc.x -= 2.0 * SP.sigmaIn * vel.x;
194 acc.y -= 2.0 * SP.sigmaIn * vel.y;
196 // Finger letting go: the reaction recorded at the end of the hold, ramped to zero.
197 if ((SP.flags & 4u) != 0u) { acc.z += react[k] * SP.releaseGain; }
199 // Drumstick: Hertz contact between a free mass and the contact patch.
200 if ((SP.flags & 8u) != 0u) {
201 let sIn = n + 4u * SP.parity;
202 let sx = react[sIn]; let sv = react[sIn + 1u]; let sMax = react[sIn + 3u];
203 let wc = posIn[2u * n + P.strikeNode];
204 let pen = wc - sx; // the stick sits on the +z side and moves toward -z
205 var F = 0.0;
206 if (pen > 0.0) { F = P.K * pow(pen, P.alpha); }
207 let dxs = nodeX(i) - P.strikeX; let dys = nodeY(j) - P.strikeY;
208 if (dxs * dxs + dys * dys <= P.strikeR2 || k == P.strikeNode) { acc.z -= F / P.patchMass; }
209 if (k == P.strikeNode) {
210 let sOut = n + 4u * (1u - SP.parity);
211 let svn = sv + P.dt * F / P.stickMass;
212 react[sOut] = sx + P.dt * svn;
213 react[sOut + 1u] = svn;
214 react[sOut + 2u] = F;
215 react[sOut + 3u] = max(sMax, F);
216 }
217 }
219 var vNew = vel + P.dt * acc;
220 if (SP.audioSlot >= 0) { hist[u32(SP.audioSlot) * n + k] = vNew.z; }
221 let pOld = vec3f(posIn[k], posIn[n + k], posIn[2u * n + k]);
222 var pNew = pOld + P.dt * vNew;
223 // Compensated update of w: the increment dt * v can be far below the
224 // float32 resolution of w, so the rounding error is carried separately.
225 let y = P.dt * vNew.z + posIn[3u * n + k];
226 let t = pOld.z + y;
227 var lo = (pOld.z - t) + y;
228 pNew.z = t;
229 if ((SP.flags & 1u) != 0u) {
230 let dxp = nodeX(i) - P.pushX; let dyp = nodeY(j) - P.pushY;
231 let inPatch = dxp * dxp + dyp * dyp <= P.pushR2;
232 if ((SP.flags & 2u) != 0u) {
233 // Acceleration the constraint has to supply to hold this node.
234 var r = 0.0;
235 if (inPatch) { r = (SP.pushV - vNew.z) / P.dt; }
236 react[k] = r;
237 }
238 if (inPatch) { pNew.z = SP.pushW; vNew.z = SP.pushV; lo = 0.0; }
239 }
240 posOut[k] = pNew.x; posOut[n + k] = pNew.y; posOut[2u * n + k] = pNew.z; posOut[3u * n + k] = lo;
241 velOut[k] = vNew.x; velOut[n + k] = vNew.y; velOut[2u * n + k] = vNew.z;
242}